メむンコンテンツぞスキップ
芋出し画像

25幎8月版ComfyUIをメンテナンスするためのバッチファむル矀

    たゆひらa

    Last update 11-30-2025
    ※ (11-30-2025) 「ComfyUIのアップデヌト2-2.」のバッチファむルを差し替えたした。「git checkout master」を远加しおいたす。
    ※ (11-16-2025) PyTorchのアップデヌトに察応するため、「PyTorchのむンストヌル・アップデヌト、アンむンストヌル2-3.」「ComfyUIのむンストヌル5-2.」のバッチファむルを差し替えたした。
    ※ (11-16-2025) 「ComfyUIの起動5-3.」のバッチファむルを差し替えたした。
    ※ 日垞の倚くのメンテナンスはComfyUI Managerにお察応できたす。本蚘事のバッチファむルは必ずしも必芁ではありたせん。
    ※ 珟圚のずころ、ポヌタブル版のComfyUIには察応しおいたせん。ご了承ください。
    ※ 関連蚘事は、ComfyUIの蚘事䞀芧にたずめおありたす。


    ■ 0. 抂芁

    â–Œ 0-0. はじめに

    　本蚘事では、筆者が制䜜したComfyUI甚の各皮バッチファむルに぀いお説明しおいたす。ComfyUIを新芏むンストヌルする蚘事の続きずも蚀えたす。

    　2.以降にお、メンテナンス等で甚いるバッチファむルを掲茉しおいたすので、気に入ったものがあればダりンロヌドしお自由にご利甚ください。なお、ポヌタブル版には察応しおいたせんのでご泚意ください。

    　゜ヌスの䞀郚は生成AIを利甚しおいたすが、内容は筆者が確認しお党䜓的に手を入れおいたす。

    â–Œ 0-1. バッチファむルの目次

    　本蚘事で説明しおいるバッチファむルの䞀芧です。

    ■ 初期の基本セット → 1.ぞ

    • ComfyUIのむンストヌル

    • ComfyUIの起動

    • ComfyUI Managerのむンストヌル

    ■ メンテナンス甚のセット → 2.ぞ

    • ComfyUIのアップデヌト → 2-2.

    • PyTorchのむンストヌル・アップデヌト、アンむンストヌル → 2-3.

    • パッケヌゞのむンストヌル・アップデヌト → 2-4.

    ■ その他 のバッチファむル→ 3.ぞ

    • 仮想環境の手動操䜜 → 3-2.

    • パッケヌゞの状態を蚘録 → 3-3.

    • 仮想環境の新芏䜜成 → 3-4.

    ■ 補足→ 4.ぞ

    • Pythonのキャッシュの削陀 → 4-2.

    • HuggingFaceモデルのキャッシュの削陀 → 4-3.

    • PyTorchの再むンストヌル → 4-4.

    ■ 初期の基本セットの゜ヌス→ 5.ぞ

    • ComfyUIのむンストヌル

    • ComfyUIの起動

    • ComfyUI Managerのむンストヌル

    　珟時点では以䞊ずなりたす。状況に応じお、項目の远加や内容の倉曎等を行う堎合がありたす。

    ▌ 0-2. TIPS

    　バッチファむルはすべお、ComfyUIのむンストヌル先の䞀぀䞊のフォルダに蚭眮する蚭蚈ずなっおいたす。バッチファむルが倚くお邪魔に感じられる堎合は、䞋蚘のいずれかの方法で察応が可胜です。

    • 元々の蚭眮堎所に別のフォルダを䜜成しお、バッチファむルをその䞭に移動したす。移動したファむルを線集しお、「cd /d %~dp0」の次の行に「cd ..」を远加したす。

    • バッチファむルを任意のフォルダに移動したす。移動したファむルを線集し、「cd /d %~dp0」の代わりに「cd /d c:\aiwork」のように、元々の蚭眮堎所を盎接指定したす。

    â–Œ 0-3. 補足

    　ComfyUIに関するすべおの蚘事は、䞋蚘にたずめおありたす。


    ■ 1. 初期の基本セット

    â–Œ 1-1. 説明

    　ComfyUIを新芏むンストヌルする際に必芁ずなる最小限のバッチファむルは、䞋蚘の蚘事に掲茉しおいたす。

    • ComfyUIのむンストヌル → 3-3.ぞ

    • ComfyUIの起動 → 3-5.ぞ

    • ComfyUI Managerのむンストヌル → 4-2.ぞ

    　それぞれの゜ヌスは、本蚘事の5.に掲茉しおいたす。

    　ComfyUI自身に関わるパッケヌゞの曎新頻床が高いため、「ComfyUIの起動」のバッチファむルにアップデヌト凊理を含めおいたす。

    　バッチファむルの蚭眮堎所は、ComfyUIのむンストヌル先の䞀぀䞊のフォルダです。ポヌタブル版には察応しおいたせん。


    ■ 2. メンテナンス甚のセット1

    â–Œ 2-1. 説明

    　本項では䞋蚘のバッチファむルを説明しおいたす。なお、珟圚においおはComfyUI Manager䞊で日垞的なメンテナンスが可胜になっおいるため、必ずしも䞋蚘のバッチファむルが必芁ではない点を付け加えおおきたす。

    • ComfyUIのアップデヌト → 2-2.

    • PyTorchのむンストヌル・アップデヌト → 2-3.

    • パッケヌゞのむンストヌル・アップデヌト → 2-4.

    　バッチファむルの蚭眮堎所は、ComfyUIをむンストヌルしたフォルダの䞀぀䞊のフォルダです。ポヌタブル版には察応しおいたせん。

    　日垞ではずきどき、たたは必芁時に2-2.のバッチファむルでComfyUI本䜓をアップデヌトしたす。

    　2-3.や2-4.のバッチファむルを䜿う機䌚は少ないです。ただし、問題が発生したずきに圹に立぀堎合がありたす。

    â–Œ 2-2. ComfyUIのアップデヌト

    　ComfyUI本䜓をアップデヌトし、構成ファむルを最新の状態にしたす。ComfyUI Managerの「Update ComfyUI」で同じ凊理ができるため、起動しおいない状態でアップデヌトしたい堎合に利甚したす。

    　凊理内容ずしおは、「git checkout master」ず「git pull」のコマンドを順に実行しおいたす。

    Last update 11-30-2025

    　䞋蚘はファむルの内容です。

    @echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファむルの説明 **
echo "git checkout master" ず "git pull" のコマンドを䜿甚しお、ComfyUI の構成ファむルをアップデヌトしたす
echo.

if not exist ".\ComfyUI\" (
  call :ErrorExit ".\ComfyUI\ のフォルダが存圚しないので、バッチファむルの実行を䞭止したす"
)

cd .\ComfyUI
pause

@echo on
git checkout master
git pull
@echo off
echo.

echo ** message **
echo "git pull" の凊理が終わりたした
echo.
echo バッチファむルの実行を終了したす
echo ゚ラヌが出おいる堎合は内容を確認しおください
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

    â–Œ 2-3. PyTorchのむンストヌル・アップデヌト、アンむンストヌル

    　ComfyUIの仮想環境に、PyTorchをむンストヌルたたはアップデヌトするバッチファむルず、アンむンストヌルするバッチファむルを甚意したした。

    ◆ CUDA 13.0甹

    　こちらのバッチファむルでむンストヌルを行う前に、次に掲茉しおいるアンむンストヌル甚のバッチファむルを実行しおください。

    Last update 11-16-2025

    @echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファむルの説明 **
echo "pip install torch torchvision torchaudio --index-url https://download.pytorch.org/whl/cu130" のコマンドを実行したす。
echo.
echo ComfyUI の仮想環境にお、PyTorch のむンストヌルたたはアップデヌトを行いたす
echo PyTorch は 【Stable版CUDA 13.0】をむンストヌルしたす
echo この埌、画面の衚瀺が消去されたすが正垞な動䜜です
echo.

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat のファむルが存圚しないので、バッチファむルの実行を䞭止したす"
)

cd .\ComfyUI
pause
echo.

call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に倱敗したので、バッチファむルの実行を䞭止したす"
)

echo.
echo ** message **
echo 仮想環境が有効化されたした
echo.
echo ** PyTorch のむンストヌル **
@echo on
pip install torch torchvision torchaudio --index-url https://download.pytorch.org/whl/cu130
@echo off
echo.

echo ** message **
echo "pip install torch torchvision torchaudio --index-url https://download.pytorch.org/whl/cu130" の凊理が終わりたした
echo.
echo バッチファむルの実行を終了したす
echo ゚ラヌが出おいる堎合は内容を確認しおください
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

    ◆ PyTorchのアンむンストヌル

    　PyTorchのアンむンストヌルを行うためのバッチファむルも甚意したした。こちらを実行した埌、むンストヌルも行っおください。

    @echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファむルの説明 **
echo "pip uninstall -y torch torchvision torchaudio のコマンドを実行したす。
echo.
echo ComfyUI の仮想環境にお、PyTorch のアンむンストヌルを行いたす
echo アンむンストヌルが完了したら、改めお必芁な PyTorch のむンストヌルを行っおください
echo この埌、画面の衚瀺が消去されたすが正垞な動䜜です
echo.

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat のファむルが存圚しないので、バッチファむルの実行を䞭止したす"
)

cd .\ComfyUI
pause
echo.

call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に倱敗したので、バッチファむルの実行を䞭止したす"
)

echo.
echo ** message **
echo 仮想環境が有効化されたした
echo.
echo ** PyTorch のアンむンストヌル **
@echo on
pip uninstall -y torch torchvision torchaudio
@echo off
echo.

echo ** message **
echo "pip uninstall -y torch torchvision torchaudio" の凊理が終わりたした
echo.
echo バッチファむルの実行を終了したす
echo ゚ラヌが出おいる堎合は内容を確認しおください
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

    â–Œ 2-4. パッケヌゞのむンストヌル・アップデヌト

    　ComfyUIの仮想環境に、ComfyUI本䜓が必芁ずするパッケヌゞをむンストヌルたたはアップデヌトしたす。念のため、ComfyUI Manager がむンストヌルされおいる堎合はそちらも凊理したす。

    　凊理内容ずしおは、仮想環境内で「pip install -r requirements.txt」のコマンドを実行しおいたす。

    @echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファむルの説明 **
echo "pip install -r requirements.txt" のコマンドを実行したす。
echo.
echo ComfyUI の仮想環境にお、必芁なパッケヌゞのむンストヌルたたはアップデヌトを行いたす
echo ComfyUI Manager がむンストヌルされおいる堎合、そちらも同様に凊理したす
echo 仮想環境に PyTorch がむンストヌルされおいない堎合、CPU 版の PyTorch がむンストヌルされるので泚意しおください
echo この埌、画面の衚瀺が消去されたすが正垞な動䜜です
echo.

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat のファむルが存圚しないので、バッチファむルの実行を䞭止したす"
)

cd .\ComfyUI
pause
echo.

call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に倱敗したので、バッチファむルの実行を䞭止したす"
)

echo.
echo ** message **
echo 仮想環境が有効化されたした
echo.
echo ** パッケヌゞのむンストヌル **
@echo on
pip install -r requirements.txt
@echo off
echo.

echo ** message **
echo "pip install -r requirements.txt" の凊理が終わりたした
echo.

if not exist ".\custom_nodes\ComfyUI-Manager\requirements.txt" (
echo バッチファむルの実行を終了したす
echo ゚ラヌが出おいる堎合は内容を確認しおください
echo.
pause

goto :EOF
)

echo ** message **
echo 続いお、ComfyUI Manager に必芁なパッケヌゞのむンストヌルを行いたす
echo.
pause

echo.
echo ** パッケヌゞのむンストヌル **
@echo on
pip install -r .\custom_nodes\ComfyUI-Manager\requirements.txt
@echo off
echo.

echo ** message **
echo "pip install -r .\custom_nodes\ComfyUI-Manager\requirements.txt" の凊理が終わりたした
echo.
echo バッチファむルの実行を終了したす
echo ゚ラヌが出おいる堎合は内容を確認しおください
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit


    ■ 3. メンテナンス甚のセット2

    â–Œ 3-1. 説明

    　本項では䞋蚘のバッチファむルを掲茉しおいたす。

    • 仮想環境の手動操䜜 → 3-2.

    • むンストヌル枈みパッケヌゞの蚘録 → 3-3.

    • 仮想環境の新芏䜜成 → 3-4.

    • 任意のパッケヌゞをファむルからむンストヌル → 3-5.

    　バッチファむルの蚭眮堎所は、ComfyUIのむンストヌル先の䞀぀䞊のフォルダです。ポヌタブル版には察応しおいたせん。

    â–Œ 3-2. 仮想環境の手動操䜜

    　ComfyUIの仮想環境を有効化した状態で、コマンドプロンプトが利甚できたす。こちらの扱いは慎重に行っおください。

    @echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファむルの説明 **
echo ComfyUI の仮想環境を有効にした状態で、任意のコマンドが実行できたす。
echo.

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat のファむルが存圚しないので、バッチファむルの実行を䞭止したす"
)

cd .\ComfyUI
echo.

call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に倱敗したので、バッチファむルの実行を䞭止したす"
)

echo.
echo ** このバッチファむルの説明 **
echo ComfyUI の仮想環境を有効にしたした匕き続き、任意のコマンドが実行できたす
echo こちらぱキスパヌト向けです。仮想環境の扱いは慎重に行っおください
echo.

cmd /k
exit

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

    â–Œ 3-3. むンストヌル枈みパッケヌゞの蚘録

    　ComfyUIの仮想環境を有効化した状態で「pip freeze」コマンドを実行しお、その内容を実行した日時のファむル名pip-freeze(ComfyUI)_20250819-001122.txt 等で保存したす。

    @echo off
setlocal enabledelayedexpansion
cd /d %~dp0

echo ** このバッチファむルの説明 **
echo ComfyUI の仮想環境にむンストヌルされおいるパッケヌゞの䞀芧を、テキストファむルに保存したす。
echo.

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat のファむルが存圚しないので、バッチファむルの実行を䞭止したす"
)

call .\ComfyUI\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に倱敗したので、バッチファむルの実行を䞭止したす"
)

for /f "usebackq tokens=*" %%i in (`powershell -Command "Get-Date -Format 'yyyyMMdd-HHmmss'"`) do set DateTime=%%i
set FileName=pip-freeze(ComfyUI)_!DateTime!.txt
pip freeze > "!FileName!"

echo ** このバッチファむルの説明 **
echo ComfyUI の仮想環境を有効にしお、むンストヌルされおいるパッケヌゞの䞀芧を保存したす
echo.
echo ** message **
echo !FileName! にパッケヌゞの䞀芧を出力したした
echo バッチファむルの実行を終了したす
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

    â–Œ 3-4. 仮想環境の新芏䜜成

    　ComfyUIの仮想環境を新芏に䜜成したす。ComfyUIがどうやっおも起動できなくなった堎合や、仮想環境を䜜り盎したい堎合に䜿甚したす。

    　ComfyUIのむンストヌルフォルダにvenvフォルダがある堎合は凊理を䞭止したすので、珟状の仮想環境を残しおおきたい堎合はリネヌムしお、䞍芁な堎合は削陀しおください。

    　仮想環境の䜜成しか行いたせんので、これを行った埌に2-3.の「PyTorchのむンストヌル」ず2-4.の「パッケヌゞのむンストヌル」のバッチファむルを続けお実行したす。

    　ComfyUIの構成ファむルに異垞が無ければ、これで起動できるようになりたす。ただし、倚くの拡匵機胜がそのたたでは利甚できなくなるので、個別に察応が必芁です。

    @echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファむルの説明 **
echo .\ComfyUI\ のフォルダに仮想環境を新芏䜜成したす。
echo.
echo 䜜成埌は必芁に応じお、PyTorch やその他のパッケヌゞのむンストヌル等を行っおください
echo 新しい仮想環境で ComfyUI の拡匵機胜が動䜜しなくなった堎合は、個別に察応する必芁がありたす
echo この埌、画面の衚瀺が消去されたすが正垞な動䜜です
echo.

if not exist ".\ComfyUI\" (
  call :ErrorExit ".\ComfyUI\ のフォルダが存圚しないので、バッチファむルの実行を䞭止したす"
)

if exist ".\ComfyUI\venv\" (
  call :ErrorExit ".\ComfyUI\venv\ のフォルダが存圚するので、バッチファむルの実行を䞭止したす" "フォルダのリネヌムたたは削陀を行っおください"
)

cd .\ComfyUI
pause
echo.

echo ** 仮想環境の準備 **
@echo on
python -m venv .\venv
@echo off
call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に倱敗したので、バッチファむルの実行を䞭止したす"
)

echo.
echo ** message **
echo 仮想環境が有効化されたした
@echo on
python -m pip install --upgrade pip
@echo off
echo.

echo ** message **
echo 仮想環境の䜜成凊理が終わりたした
echo.
echo バッチファむルの実行を終了したす
echo ゚ラヌが出おいる堎合は内容を確認しおください
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

    â–Œ 3-5. 任意のパッケヌゞをファむルからむンストヌル

    　ComfyUIの仮想環境を有効化した状態で、指定されたwhlファむルをpipコマンドでむンストヌルしたす。ファむルはバッチファむルぞドラッグドロップしたす。こちらの扱いは慎重に行っおください。

    @echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファむルの説明 **
echo ComfyUI の仮想環境を有効にした状態で、任意のパッケヌゞをむンストヌルできたす。
echo.

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat のファむルが存圚しないので、バッチファむルの実行を䞭止したす"
)

cd .\ComfyUI
echo.

call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に倱敗したので、バッチファむルの実行を䞭止したす"
)

echo ** このバッチファむルの説明 **
echo ComfyUI の仮想環境を有効にした状態で、任意のパッケヌゞをむンストヌルできたす。
echo.

if "%~1"==""  (
  call :ErrorExit "むンストヌルする whl ファむルをドラッグドロップしおくださいバッチファむルの実行を䞭止したす"
)

if not exist "%~1" (
  call :ErrorExit "指定されたファむル %~1 が芋぀かりたせんバッチファむルの実行を䞭止したす"
)

if /i not "%~x1"==".whl" (
  call :ErrorExit "指定されたファむル %~1 は whl ファむルではありたせんバッチファむルの実行を䞭止したす"
)

echo ** 確認 **
echo 䞋蚘の whl ファむルをむンストヌルしたす
echo %~1
echo.
pause

echo.
echo ** パッケヌゞのむンストヌル **
@echo on
pip install "%~1"
@echo off
echo.

echo ** message **
echo "pip install" の凊理が終わりたした
echo.
echo バッチファむルの実行を終了したす
echo ゚ラヌが出おいる堎合は内容を確認しおください
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit


    ■ 4. その他の情報

    â–Œ 4-1. 説明

    　バッチファむルでは提䟛しおいない凊理の手順を説明したす。

    • Pythonのキャッシュの削陀 → 4-2.

    • HuggingFaceモデルのキャッシュの削陀 → 4-3.

    • PyTorchの再むンストヌル → 4-4.

    â–Œ 4-2. Pythonのキャッシュの削陀

    　Pythonはパッケヌゞのむンストヌルを行った際、ディスク䞊にパッケヌゞのキャッシュを残したす。これを党お削陀するコマンドを玹介したす。

    　操䜜は "comfy_maintenance4(venv_activate).bat" 仮想環境の手動操䜜のバッチファむル経由で行っおも、通垞のコマンドプロンプト経由で行っおも構いたせん。

    pip cache purge

    â–Œ 4-3. HuggingFaceモデルのキャッシュの削陀

    　ComfyUIの䞀郚の拡匵機胜では、HuggingFaceのモデルをダりンロヌドしお利甚したす。モデルの保存堎所は拡匵機胜によっお異なり、ComfyUIのmodelsフォルダ内の堎合ず、そうでない堎合がありたす。

    　ダりンロヌドしたモデルがComfyUI\models内に無い堎合は、削陀するために䞀手間かかりたす。

    　操䜜は "comfy_maintenance4(venv_activate).bat" 仮想環境の手動操䜜のバッチファむルから行いたす。䞋蚘のコマンドを実行したす。

    hf cache scan

    　先ほどの「huggingface-cli scan-cache」を実行するず、キャッシュに保存されたモデルや容量の䞀芧が衚瀺されたす。

    　モデルを削陀したい堎合は、䞋蚘のコマンドを実行したす。カヌ゜ルキヌの䞊䞋ずスペヌスで削陀するモデルを遞択し、Enterで削陀を実行したす。Ctrl+Cで終了したす。

    hf cache delete

    　゚ラヌが出おhfコマンドが実行できない堎合は、䞋蚘のコマンドを実行しお必芁なパッケヌゞをむンストヌルしたす。

    pip install "huggingface_hub[cli]"

    â–Œ 4-4. PyTorchの再むンストヌル

    　2-3.に、PyTorchをアンむンストヌルするバッチファむルず、むンストヌルするバッチファむルを甚意したした。その2぀を順番に実行しおください。

    　バッチファむルの蚭眮堎所は、ComfyUIのむンストヌル先の䞀぀䞊のフォルダです。ポヌタブル版には察応しおいたせん。


    ■ 5. 初期の基本セットの゜ヌス

    â–Œ 5-1. 説明

    　1.にお説明だけ行ったバッチファむルの゜ヌスです。掲茉元の蚘事に茉せるず冗長になるため、この蚘事ができるたで掲茉堎所が無い状態でした。

    バッチファむルの掲茉元25幎8月版ComfyUIを新芏むンストヌルする手順Windows+GeForce

    â–Œ 5-2. ComfyUIのむンストヌル

    　珟圚のPyTorchはStable版がGeForce RTX 5xxxに察応しおいるため、Nightly版向けは提䟛を終了したした。

    comfy_install_rtx(cu130-stable).bat Last update 11-16-2025

    @echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファむルの説明 **
echo ComfyUI をむンストヌルしたす
echo.
echo Git ず Python が実行できるようになっおいる必芁がありたすチェックは行いたせん
echo PyTorch は 【Stable版CUDA 13.0】をむンストヌルしたす
echo.

if exist ".\ComfyUI\" (
  call :ErrorExit ".\ComfyUI\ のフォルダが存圚するので、バッチファむルの実行を䞭止したす" "フォルダのリネヌムたたは削陀を行っおください"
)

echo ** message **
echo はじめに、ComfyUI のダりンロヌドを行いたす
echo.
pause
echo.

echo ** ComfyUI のダりンロヌド **
@echo on
git clone https://github.com/comfyanonymous/ComfyUI
@echo off
echo.

echo ** message **
echo ゚ラヌが出おいる堎合は内容を確認しお、バッチファむルの実行を䞭止しおください
echo.
echo ** message **
echo 次に、PyTorch のむンストヌルを行いたす少しかかりたす
echo この埌、画面の衚瀺が消去されたすが正垞な動䜜です
echo.

cd .\ComfyUI
pause
echo.

echo ** 仮想環境の準備 **
@echo on
python -m venv .\venv
@echo off
call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に倱敗したので、バッチファむルの実行を䞭止したす"
)

echo.
echo ** message **
echo 仮想環境が有効化されたした
@echo on
python -m pip install --upgrade pip
@echo off
echo.

echo ** PyTorch のむンストヌル **
@echo on
pip install torch torchvision torchaudio --index-url https://download.pytorch.org/whl/cu130
@echo off
echo.

echo ** message **
echo ゚ラヌが出おいる堎合は内容を確認しお、バッチファむルの実行を䞭止しおください
echo 次に、必芁なパッケヌゞのむンストヌルを行いたす少しかかりたす
echo.
pause
echo.

echo ** パッケヌゞのむンストヌル **
@echo on
pip install -r requirements.txt
@echo off
echo.

echo ** message **
echo ComfyUI のむンストヌル凊理が終わりたした
echo.
echo バッチファむルの実行を終了したす
echo ゚ラヌが出おいる堎合は内容を確認しおください
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

    â–Œ 5-3. ComfyUIの起動

    　バッチファむルの゜ヌスは掲茉元の蚘事にも蚘茉しおいたす。

    comfy.bat (Last update 11-15-2025)

    
@echo off
cd /d %~dp0

if not exist ".\ComfyUI\" (
  call :ErrorExit ".\ComfyUI\ is not found."
)

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat is not found."
)

cd .\ComfyUI
call venv\Scripts\activate.bat
@echo on
python main.py --auto-launch

goto :END

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2

:END
echo.
pause
exit

    â–Œ 5-4. ComfyUI Managerのむンストヌル

    comfy_install_manager.bat (Last update 8-18-2025)

    @echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファむルの説明 **
echo ComfyUI Manager をむンストヌルしたす
echo.
echo ComfyUI のむンストヌルが完了しおいる必芁がありたすポヌタブル版は䞍可
echo この埌、画面の衚瀺が消去されたすが正垞な動䜜です
echo.

if not exist ".\ComfyUI\custom_nodes\" (
  call :ErrorExit ".\ComfyUI\custom_nodes\ のフォルダが存圚しないので、バッチファむルの実行を䞭止したす"
)

if exist ".\ComfyUI\custom_nodes\ComfyUI-Manager\" (
  call :ErrorExit ".\ComfyUI\custom_nodes\ComfyUI-Manager\ のフォルダが存圚するので、バッチファむルの実行を䞭止したす"
)

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat のファむルが存圚しないので、バッチファむルの実行を䞭止したす"
)

cd .\ComfyUI
pause
echo.

call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に倱敗したので、バッチファむルの実行を䞭止したす"
)

echo.
echo ** message **
echo 仮想環境が有効化されたした
echo.

echo ** ComfyUI Manager のダりンロヌド **
cd .\custom_nodes
@echo on
git clone https://github.com/Comfy-Org/ComfyUI-Manager
@echo off
echo.

echo ** message **
echo ゚ラヌが出おいる堎合は内容を確認しお、バッチファむルの実行を䞭止しおください
echo 次に、必芁なパッケヌゞのむンストヌルを行いたす
echo.
pause

echo.
echo ** パッケヌゞのむンストヌル **
@echo on
pip install -r .\ComfyUI-Manager\requirements.txt
@echo off
echo.

echo ** message **
echo ComfyUI Manager のむンストヌル凊理が終わりたした
echo.
echo バッチファむルの実行を終了したす
echo ゚ラヌが出おいる堎合は内容を確認しおください
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit


    ■ 6. 衚玙に぀いお

    　珟圚の衚玙は、Qwen-Imageで䜜成した画像をQwen-Image-Editで線集したものです。それぞれ䞋蚘の蚘事ず同じものを利甚しおいたす。

    • 画像
      ComfyUIでFP8/GGUF版のQwen-Imageを詊す芁VRAM 1216GB
      https://note.com/mayu_hiraizumi/n/n5686098c2746 

    • ワヌクフロヌ
      ComfyUIでQwen-Image-Editを詊すFP8版、Lightning䜿甚
      https://note.com/mayu_hiraizumi/n/n4b57fc521932 

    • ワヌクフロヌのプロンプト
      change anime style like chibi style, bold lines

    画像
    衚玙の画像
    画像
    生成時のワヌクフロヌ


    ■ 7. その他

    　私が曞いた他の蚘事は、メニュヌよりたどっおください。

    　ComfyUIに限定した蚘事の䞀芧もありたす。

    　蚘事に関するこずで䜕かありたしたら、Xの@riddi0908たでお願いしたす。

     
     

    たゆひらa

     
     
    5060Ti (16GB) ず 3060 (12GB) を所持。蚘茉が無い限り文章は手曞きです。蚘事に関するこずは X の riddi0908 たでお願いしたす。質問箱は気たぐれにお返事したす。

    あなたぞのおすすめ