Async と Await を使用した非同期プログラミング (Visual Basic)

Task 非同期プログラミング (TAP) モデルは、一般的な非同期コーディングよりも抽象化のレイヤーを提供します。 このモデルでは、通常と同じように、ステートメントのシーケンスとしてコードを記述します。 違いは、コンパイラが各ステートメントを処理し、次のステートメントの処理を開始する前に、タスク ベースのコードを読み取ることができる点です。 このモデルを実現するために、コンパイラは多くの変換を実行して各タスクを完了します。 一部のステートメントでは、作業を開始し、進行中の作業を表す Task オブジェクトを返すことができます。 コンパイラはこれらの変換を解決する必要があります。 タスク非同期プログラミングの目的は、ステートメントのシーケンスのように読み取るが、より複雑な順序で実行されるコードを有効にすることです。 実行は、外部リソースの割り当てとタスクの完了に基づいています。

タスク非同期プログラミング モデルは、非同期タスクを含むプロセスの指示をユーザーが行う方法に似ています。 この記事では、朝食を作成する手順の例を使用して、 Async キーワードと Await キーワードを使用して、一連の非同期命令を含むコードを簡単に推論できるようにする方法を示します。 朝食を作る手順は、一覧として提供される場合があります。

1. コーヒーを一杯注ぎます。
2. フライパンを熱し、2個の卵を揚げます。
3. 3つのハッシュブラウンのパテを調理します。
4. 2 枚のパンをトーストします。
5. トーストにバターとジャムを広げます。
6. オレンジジュースを1杯注ぎます。

調理の経験がある場合は、これらの手順を 非同期的に完了できます。 あなたは卵のためにパンを温め始め、ハッシュブラウンを調理し始めます。 あなたはトースターにパンを入れて、卵を調理し始めます。 プロセスの各ステップで、まずタスクを開始し、その後、注意を払う準備が整った他のタスクに移行します。

朝食の調理は、並列ではない非同期作業の良い例です。 1 人のユーザー (またはスレッド) がすべてのタスクを処理できます。 前のタスクが完了する前に次のタスクを開始することで、1 人のユーザーが朝食を非同期的に行うことができます。 誰かがプロセスを積極的に見ているかどうかに関係なく、各調理タスクが進行します。 卵の鍋を温め始めるとすぐに、ハッシュブラウンの調理を始めることができます。 ハッシュブラウンが調理し始めたら、トースターにパンを入れることができます。

並列アルゴリズムの場合は、調理する複数のユーザー (または複数のスレッド) が必要です。 ある人が卵を調理し、別の人がハッシュブラウンを調理します。 各ユーザーは、1 つの特定のタスクに焦点を当てます。 調理中の各人 (または各スレッド) は、現在のタスクの完了を同期的に待機してブロックされます (ひっくり返す準備ができているハッシュブラウン、トースターで焼く準備ができているパンなど)。

Visual Basic コード ステートメントとして記述された同期命令の同じ一覧を考えてみましょう。

Sub Main()
    Dim cup As Coffee = PourCoffee()
    Console.WriteLine("coffee is ready")

    Dim eggs As Egg = FryEggs(2)
    Console.WriteLine("eggs are ready")

    Dim hashBrown As HashBrown = FryHashBrowns(3)
    Console.WriteLine("hash browns are ready")

    Dim toast As Toast = ToastBread(2)
    ApplyButter(toast)
    ApplyJam(toast)
    Console.WriteLine("toast is ready")

    Dim oj As Juice = PourOJ()
    Console.WriteLine("oj is ready")
    Console.WriteLine("Breakfast is ready!")
End Sub

Private Function PourOJ() As Juice
    Console.WriteLine("Pouring orange juice")
    Return New Juice()
End Function

Private Sub ApplyJam(toast As Toast)
    Console.WriteLine("Putting jam on the toast")
End Sub

Private Sub ApplyButter(toast As Toast)
    Console.WriteLine("Putting butter on the toast")
End Sub

Private Function ToastBread(slices As Integer) As Toast
    For slice As Integer = 0 To slices - 1
        Console.WriteLine("Putting a slice of bread in the toaster")
    Next
    Console.WriteLine("Start toasting...")
    Task.Delay(3000).Wait()
    Console.WriteLine("Remove toast from toaster")

    Return New Toast()
End Function

Private Function FryHashBrowns(patties As Integer) As HashBrown
    Console.WriteLine($"putting {patties} hash brown patties in the pan")
    Console.WriteLine("cooking first side of hash browns...")
    Task.Delay(3000).Wait()
    For patty As Integer = 0 To patties - 1
        Console.WriteLine("flipping a hash brown patty")
    Next
    Console.WriteLine("cooking the second side of hash browns...")
    Task.Delay(3000).Wait()
    Console.WriteLine("Put hash browns on plate")

    Return New HashBrown()
End Function

Private Function FryEggs(howMany As Integer) As Egg
    Console.WriteLine("Warming the egg pan...")
    Task.Delay(3000).Wait()
    Console.WriteLine($"cracking {howMany} eggs")
    Console.WriteLine("cooking the eggs ...")
    Task.Delay(3000).Wait()
    Console.WriteLine("Put eggs on plate")

    Return New Egg()
End Function

Private Function PourCoffee() As Coffee
    Console.WriteLine("Pouring coffee")
    Return New Coffee()
End Function

上記のコードを自分で試す場合は、次の追加の型を定義する必要があります。

Friend Class HashBrown
End Class

Friend Class Coffee
End Class

Friend Class Egg
End Class

Friend Class Juice
End Class

Friend Class Toast
End Class

これらの手順をコンピューターとして解釈する場合、朝食の準備には約 30 分かかります。 期間は、個々のタスク時間の合計です。 コンピューターは、すべての作業が完了するまで各ステートメントをブロックし、次のタスク ステートメントに進みます。 この方法には時間がかかる場合があります。 朝食の例では、コンピューター メソッドによって満足できない朝食が作成されます。 同期リストの後のタスク (パンのトーストなど) は、前のタスクが完了するまで開始されません。 朝食の準備が整う前に、一部の食べ物が冷たくなります。

コンピューターで命令を非同期的に実行する場合は、非同期コードを記述する必要があります。 クライアント プログラムを記述するときに、UI がユーザー入力に対して応答性を持たせたい。 Web からデータをダウンロードする際に、アプリケーションですべての対話をフリーズさせるべきではありません。 サーバー プログラムを記述するときは、他の要求を処理している可能性のあるスレッドをブロックしたくない場合があります。 非同期の代替手段がある場合に同期コードを使用すると、コストを抑えてスケールアウトする能力が損なわれます。 ブロックされたスレッドに対して支払います。

成功した最新のアプリには非同期コードが必要です。 言語がサポートされていない場合、非同期コードを記述するには、コールバック、完了イベント、またはその他の手段が必要です。これにより、コードの元の意図が隠されます。 同期コードの利点は、スキャンと理解を容易にするステップ バイ ステップアクションです。 従来の非同期モデルでは、コードの基本的なアクションではなく、コードの非同期の性質に重点を置く必要があります。

ブロックしない、代わりに待機する

前のコードでは、残念なプログラミング手法である非同期操作を実行するための同期コードの記述が強調されています。 このコードは、現在のスレッドが他の作業を行うことをブロックします。 実行中のタスクがある間、コードはスレッドを中断しません。 このモデルの結果は、パンを入れた後にトースターを見つめるのと似ています。 中断は無視し、パンがポップアップするまで他のタスクを開始しません。 あなたはバターとジャムを冷蔵庫から取り出しません。 ストーブから火が出るのを見逃すかもしれません。 パンをトーストし、他の懸念事項を同時に処理する必要があります。 これは、コードにも当てはまります。

まず、タスクの実行中にスレッドがブロックされないようにコードを更新します。 Await キーワードは、タスクを開始し、タスクの完了時に実行を続行する非ブロッキングの方法を提供します。 朝食コードの単純な非同期バージョンは、次のスニペットのようになります。

Module AsyncBreakfastProgram
    Async Function Main() As Task
        Dim cup As Coffee = PourCoffee()
        Console.WriteLine("coffee is ready")

        Dim eggs As Egg = Await FryEggsAsync(2)
        Console.WriteLine("eggs are ready")

        Dim hashBrown As HashBrown = Await FryHashBrownsAsync(3)
        Console.WriteLine("hash browns are ready")

        Dim toast As Toast = Await ToastBreadAsync(2)
        ApplyButter(toast)
        ApplyJam(toast)
        Console.WriteLine("toast is ready")

        Dim oj As Juice = PourOJ()
        Console.WriteLine("oj is ready")
        Console.WriteLine("Breakfast is ready!")
    End Function

    Private Async Function ToastBreadAsync(slices As Integer) As Task(Of Toast)
        For slice As Integer = 0 To slices - 1
            Console.WriteLine("Putting a slice of bread in the toaster")
        Next
        Console.WriteLine("Start toasting...")
        Await Task.Delay(3000)
        Console.WriteLine("Remove toast from toaster")

        Return New Toast()
    End Function

    Private Async Function FryHashBrownsAsync(patties As Integer) As Task(Of HashBrown)
        Console.WriteLine($"putting {patties} hash brown patties in the pan")
        Console.WriteLine("cooking first side of hash browns...")
        Await Task.Delay(3000)
        For patty As Integer = 0 To patties - 1
            Console.WriteLine("flipping a hash brown patty")
        Next
        Console.WriteLine("cooking the second side of hash browns...")
        Await Task.Delay(3000)
        Console.WriteLine("Put hash browns on plate")

        Return New HashBrown()
    End Function

    Private Async Function FryEggsAsync(howMany As Integer) As Task(Of Egg)
        Console.WriteLine("Warming the egg pan...")
        Await Task.Delay(3000)
        Console.WriteLine($"cracking {howMany} eggs")
        Console.WriteLine("cooking the eggs ...")
        Await Task.Delay(3000)
        Console.WriteLine("Put eggs on plate")

        Return New Egg()
    End Function

    Private Function PourCoffee() As Coffee
        Console.WriteLine("Pouring coffee")
        Return New Coffee()
    End Function

    Private Function PourOJ() As Juice
        Console.WriteLine("Pouring orange juice")
        Return New Juice()
    End Function

    Private Sub ApplyJam(toast As Toast)
        Console.WriteLine("Putting jam on the toast")
    End Sub

    Private Sub ApplyButter(toast As Toast)
        Console.WriteLine("Putting butter on the toast")
    End Sub
End Module

このコードは、 FryEggs、 FryHashBrowns、および ToastBread の元のメソッド本体を更新して、 Task(Of Egg)、 Task(Of HashBrown)、および Task(Of Toast) オブジェクトをそれぞれ返します。 更新されたメソッド名には、"Async" サフィックス ( FryEggsAsync、 FryHashBrownsAsync、および ToastBreadAsync) が含まれます。 Main関数は、Task オブジェクトを返しますが、Return式は設計されていません。

更新されたコードに朝食の例を適用してみましょう。 卵またはハッシュブラウンが調理されている間、スレッドはブロックされませんが、コードは現在の作業が完了するまで他のタスクも開始しません。 あなたはまだトースターにパンを入れて、パンがポップアップするまでトースターを見つめますが、今では中断に対応することができます。 複数の注文が行われるレストランでは、別の料理が既に調理されている間に、料理人は新しい注文を開始できます。

更新されたコードでは、朝食に対して作業しているスレッドは、未完了の開始タスクを待機している間はブロックされません。 一部のアプリケーションでは、この変更だけで十分です。 Web からのデータのダウンロード中にユーザーの操作をサポートするようにアプリを有効にすることができます。 他のシナリオでは、前のタスクが完了するのを待っている間に他のタスクを開始できます。

タスクを同時に開始する

ほとんどの操作では、複数の独立したタスクをすぐに開始できます。 各タスクが完了したら、開始する準備ができている他の作業を開始できます。 この手法を朝食の例に適用すると、朝食をより迅速に準備できます。 また、同じ時間に近い準備ができたので、ホットブレックファーストを楽しむことができます。

Task クラスと関連する型を使用して、進行中のタスクにこのスタイルの推論を適用します。 この方法では、実際の朝食の作成方法に似たコードを記述できます。 卵、ハッシュブラウン、トーストを同時に調理し始めます。 各食品にアクションが必要な場合は、そのタスクに注意を向け、アクションの処理を行い、注意が必要な他の処理を待ちます。

コードでタスクを開始し、作業を表す Task オブジェクトを保持します。 タスクの Await 式を使用して、結果が準備できるまで処理を遅らせます。

これらの変更を朝食コードに適用します。 最初の手順では、 Await 式を使用するのではなく、操作の開始時にタスクを格納します。

Dim cup As Coffee = PourCoffee()
Console.WriteLine("Coffee is ready")

Dim eggsTask As Task(Of Egg) = FryEggsAsync(2)
Dim eggs As Egg = Await eggsTask
Console.WriteLine("Eggs are ready")

Dim hashBrownTask As Task(Of HashBrown) = FryHashBrownsAsync(3)
Dim hashBrown As HashBrown = Await hashBrownTask
Console.WriteLine("Hash browns are ready")

Dim toastTask As Task(Of Toast) = ToastBreadAsync(2)
Dim toast As Toast = Await toastTask
ApplyButter(toast)
ApplyJam(toast)
Console.WriteLine("Toast is ready")

Dim oj As Juice = PourOJ()
Console.WriteLine("Oj is ready")
Console.WriteLine("Breakfast is ready!")

これらの変更は、朝食の準備を早めるのに役立つわけではありません。 Await式は、開始するとすぐにすべてのタスクに適用されます。 次の手順では、朝食を提供する前に、ハッシュ ブラウンと卵の Await 式をメソッドの最後に移動します。

Dim cup As Coffee = PourCoffee()
Console.WriteLine("Coffee is ready")

Dim eggsTask As Task(Of Egg) = FryEggsAsync(2)
Dim hashBrownTask As Task(Of HashBrown) = FryHashBrownsAsync(3)
Dim toastTask As Task(Of Toast) = ToastBreadAsync(2)

Dim toast As Toast = Await toastTask
ApplyButter(toast)
ApplyJam(toast)
Console.WriteLine("Toast is ready")
Dim oj As Juice = PourOJ()
Console.WriteLine("Oj is ready")

Dim eggs As Egg = Await eggsTask
Console.WriteLine("Eggs are ready")
Dim hashBrown As HashBrown = Await hashBrownTask
Console.WriteLine("Hash browns are ready")

Console.WriteLine("Breakfast is ready!")

これで、準備に約 20 分かかる非同期の朝食が用意されました。 一部のタスクは同時に実行されるため、合計クック時間が短縮されます。

コードの更新では、調理時間を短縮することで準備プロセスが向上しますが、卵とハッシュ ブラウンを焼くことで回帰が発生します。 すべての非同期タスクを一度に開始します。 必要なときのみ、タスクの結果を待機します。 コードは、異なるマイクロサービスに要求を行い、結果を 1 つのページに結合する Web アプリケーションのプログラムに似ている場合があります。 すべての要求をすぐに行い、それらのすべてのタスクに Await 式を適用し、Web ページを作成します。

タスクを通じて構成をサポートする

前のコードリビジョンは、トーストを除き、朝食の準備を同時に行うのに役立ちます。 トーストを作成するプロセスは、同期操作 (トーストにバターとジャムを広げる) を伴う非同期操作 (パンのトースト) の 構成 です。 この例では、非同期プログラミングに関する重要な概念を示します。

以前の更新では、実行中のタスクを保持するために Task または Task<TResult> オブジェクトを使用する方法について学習しました。 各タスクの結果を使用する前に待機します。 次の手順では、他の作業の組み合わせを表すメソッドを作成します。 朝食を出す前に、まずパンをトーストし、その後にバターとジャムを塗る準備をしなければなりません。

この作業は、次のコードで表すことができます。

Async Function MakeToastWithButterAndJamAsync(number As Integer) As Task(Of Toast)
    Dim toast As Toast = Await ToastBreadAsync(number)
    ApplyButter(toast)
    ApplyJam(toast)

    Return toast
End Function

MakeToastWithButterAndJamAsync メソッドのシグネチャには、メソッドにAsync式が含まれており、非同期操作が含まれていることをコンパイラに通知するAwait修飾子があります。 このメソッドは、パンをトーストし、バターとジャムを広げるタスクを表します。 このメソッドは、3 つの操作の構成を表す Task<TResult> オブジェクトを返します。

変更されたコードのメイン ブロックは次のようになります。

Async Function Main() As Task
    Dim cup As Coffee = PourCoffee()
    Console.WriteLine("coffee is ready")

    Dim eggsTask = FryEggsAsync(2)
    Dim hashBrownTask = FryHashBrownsAsync(3)
    Dim toastTask = MakeToastWithButterAndJamAsync(2)

    Dim eggs = Await eggsTask
    Console.WriteLine("eggs are ready")

    Dim hashBrown = Await hashBrownTask
    Console.WriteLine("hash browns are ready")

    Dim toast = Await toastTask
    Console.WriteLine("toast is ready")

    Dim oj As Juice = PourOJ()
    Console.WriteLine("oj is ready")
    Console.WriteLine("Breakfast is ready!")
End Function

このコード変更は、非同期コードを操作するための重要な手法を示しています。 タスクを作成するには、タスクを返す新しいメソッドに操作を分離します。 そのタスクを待機するタイミングを選択できます。 他のタスクを同時に開始できます。

非同期例外の処理

この時点まで、コードでは、すべてのタスクが正常に完了したと暗黙的に想定されます。 非同期メソッドでも、対応する同期メソッドと同様に、例外がスローされます。 例外とエラー処理の非同期サポートの目標は、一般的に非同期サポートの場合と同じです。 ベスト プラクティスは、一連の同期ステートメントのように読み取るコードを記述することです。 正常に完了できない場合、タスクによって例外がスローされます。 Await式が開始タスクに適用されると、クライアント コードはこれらの例外をキャッチできます。

朝食の例では、パンをトーストしている間にトースターが火をキャッチするとします。 ToastBreadAsync メソッドを次のコードに一致するように変更することで、この問題をシミュレートできます。

Private Async Function ToastBreadAsync(slices As Integer) As Task(Of Toast)
    For slice As Integer = 0 To slices - 1
        Console.WriteLine("Putting a slice of bread in the toaster")
    Next
    Console.WriteLine("Start toasting...")
    Await Task.Delay(2000)
    Console.WriteLine("Fire! Toast is ruined!")
    Throw New InvalidOperationException("The toaster is on fire")
    Await Task.Delay(1000)
    Console.WriteLine("Remove toast from toaster")

    Return New Toast()
End Function

コードを変更した後、アプリケーションを実行し、出力を確認します。

Pouring coffee
Coffee is ready
Warming the egg pan...
putting 3 hash brown patties in the pan
Cooking first side of hash browns...
Putting a slice of bread in the toaster
Putting a slice of bread in the toaster
Start toasting...
Fire! Toast is ruined!
Flipping a hash brown patty
Flipping a hash brown patty
Flipping a hash brown patty
Cooking the second side of hash browns...
Cracking 2 eggs
Cooking the eggs ...
Put hash browns on plate
Put eggs on plate
Eggs are ready
Hash browns are ready
Unhandled exception. System.InvalidOperationException: The toaster is on fire
   at AsyncBreakfast.Program.ToastBreadAsync(Int32 slices) in Program.vb:line 65
   at AsyncBreakfast.Program.MakeToastWithButterAndJamAsync(Int32 number) in Program.vb:line 36
   at AsyncBreakfast.Program.Main(String[] args) in Program.vb:line 24
   at AsyncBreakfast.Program.<Main>(String[] args)

トースターが火をキャッチし、システムが例外を観察するまでの間に、かなりの数のタスクが終了していることに注意してください。 非同期的に実行されるタスクが例外をスローすると、そのタスクに エラーが発生します。 Task オブジェクトは、Task.Exception プロパティでスローされた例外を保持します。 エラーが発生したタスクは、式がタスクに適用されると例外をAwaitします。

このプロセスは、次の 2 つの重要なメカニズムで説明されています。

• エラーが発生したタスクに例外を格納する方法。
• エラー発生タスクでコードが待機 (Await) するとき、例外がアンパックされて再スローされる方法。

非同期的に実行されているコードが例外をスローすると、例外は Task オブジェクトに格納されます。 Task.Exception プロパティは、非同期作業中に複数の例外がスローされる可能性があるため、AggregateException オブジェクトです。 スローされた例外は、AggregateException.InnerExceptions コレクションに追加されます。 Exception プロパティが null の場合、新しいAggregateException オブジェクトが作成され、スローされた例外がコレクション内の最初の項目になります。

エラーが発生したタスクの最も一般的なシナリオは、 Exception プロパティに 1 つの例外が含まれていることです。 コードはエラーになったタスクを待機しているとき、コレクション内の最初の AggregateException.InnerExceptions 例外を再スローします。 この結果は、この例からの出力で、InvalidOperationException オブジェクトではなくAggregateException オブジェクトが表示される理由です。 最初の内部例外を抽出すると、非同期メソッドの操作が、対応する同期メソッドの操作にできるだけ似てくるようになります。 シナリオで複数の例外が生成される可能性がある場合は、コードの Exception プロパティを調べることができます。

次のセクションに進む前に、 ToastBreadAsync メソッドで次の 2 つのステートメントをコメントアウトします。 また火事を起こしたくない。

' Console.WriteLine("Fire! Toast is ruined!")
' Throw New InvalidOperationException("The toaster is on fire")

await 式をタスクに効率的に適用する

Await クラスのメソッドを使用して、前のコードの最後にある一連のTask式を改善できます。 1 つの API は WhenAll メソッドであり、引数リスト内のすべてのタスクが完了したときに完了する Task オブジェクトを返します。 次のコードは、このメソッドを示しています。

Await Task.WhenAll(eggsTask, hashBrownTask, toastTask)
Console.WriteLine("Eggs are ready")
Console.WriteLine("Hash browns are ready")
Console.WriteLine("Toast is ready")
Console.WriteLine("Breakfast is ready!")

もう 1 つのオプションは、 WhenAny メソッドを使用することです。このメソッドは、引数のいずれかが完了したときに完了する Task(Of Task) オブジェクトを返します。 タスクが完了したことがわかっているので、返されたタスクを待つことができます。 次のコードは、 WhenAny メソッドを使用して、最初のタスクが完了するのを待機し、その結果を処理する方法を示しています。 完了したタスクの結果を処理した後、 WhenAny メソッドに渡されたタスクの一覧から完了したタスクを削除します。

Module ConcurrentBreakfastProgram
    Async Function Main() As Task
        Dim cup As Coffee = PourCoffee()
        Console.WriteLine("Coffee is ready")

        Dim eggsTask As Task(Of Egg) = FryEggsAsync(2)
        Dim hashBrownTask As Task(Of HashBrown) = FryHashBrownsAsync(3)
        Dim toastTask As Task(Of Toast) = MakeToastWithButterAndJamAsync(2)

        Dim breakfastTasks As New List(Of Task) From {eggsTask, hashBrownTask, toastTask}
        While breakfastTasks.Count > 0
            Dim finishedTask As Task = Await Task.WhenAny(breakfastTasks)
            If finishedTask Is eggsTask Then
                Console.WriteLine("eggs are ready")
            ElseIf finishedTask Is hashBrownTask Then
                Console.WriteLine("hash browns are ready")
            ElseIf finishedTask Is toastTask Then
                Console.WriteLine("toast is ready")
            End If
            Await finishedTask
            breakfastTasks.Remove(finishedTask)
        End While

        Dim oj As Juice = PourOJ()
        Console.WriteLine("oj is ready")
        Console.WriteLine("Breakfast is ready!")
    End Function

    Async Function MakeToastWithButterAndJamAsync(number As Integer) As Task(Of Toast)
        Dim toast As Toast = Await ToastBreadAsync(number)
        ApplyButter(toast)
        ApplyJam(toast)

        Return toast
    End Function

    Private Async Function ToastBreadAsync(slices As Integer) As Task(Of Toast)
        For slice As Integer = 0 To slices - 1
            Console.WriteLine("Putting a slice of bread in the toaster")
        Next
        Console.WriteLine("Start toasting...")
        Await Task.Delay(3000)
        Console.WriteLine("Remove toast from toaster")

        Return New Toast()
    End Function

    Private Async Function FryHashBrownsAsync(patties As Integer) As Task(Of HashBrown)
        Console.WriteLine($"putting {patties} hash brown patties in the pan")
        Console.WriteLine("cooking first side of hash browns...")
        Await Task.Delay(3000)
        For patty As Integer = 0 To patties - 1
            Console.WriteLine("flipping a hash brown patty")
        Next
        Console.WriteLine("cooking the second side of hash browns...")
        Await Task.Delay(3000)
        Console.WriteLine("Put hash browns on plate")

        Return New HashBrown()
    End Function

    Private Async Function FryEggsAsync(howMany As Integer) As Task(Of Egg)
        Console.WriteLine("Warming the egg pan...")
        Await Task.Delay(3000)
        Console.WriteLine($"cracking {howMany} eggs")
        Console.WriteLine("cooking the eggs ...")
        Await Task.Delay(3000)
        Console.WriteLine("Put eggs on plate")

        Return New Egg()
    End Function

    Private Function PourCoffee() As Coffee
        Console.WriteLine("Pouring coffee")
        Return New Coffee()
    End Function

    Private Function PourOJ() As Juice
        Console.WriteLine("Pouring orange juice")
        Return New Juice()
    End Function

    Private Sub ApplyJam(toast As Toast)
        Console.WriteLine("Putting jam on the toast")
    End Sub

    Private Sub ApplyButter(toast As Toast)
        Console.WriteLine("Putting butter on the toast")
    End Sub
End Module

コード スニペットの末尾近くで、 Await finishedTask 式に注目してください。 この行は、 Task.WhenAny が Task(Of Task) (完了したタスクを含むラッパー タスク) を返すので重要です。 Await Task.WhenAnyの際にはラッパー タスクが完了するのを待ち、最初に完了したタスクが実際の結果となります。 ただし、そのタスクの結果を取得したり、例外が適切にスローされるようにするには、完了したタスク自体 (Awaitに格納) をfinishedTaskする必要があります。 タスクが完了したことを知っていても、タスクを再度待機すると、その結果にアクセスしたり、エラーの原因となった可能性のある例外を処理したりできます。

最終的なコードを確認する

コードの最終バージョンは次のようになります。

Module ConcurrentBreakfastProgram
    Async Function Main() As Task
        Dim cup As Coffee = PourCoffee()
        Console.WriteLine("Coffee is ready")

        Dim eggsTask As Task(Of Egg) = FryEggsAsync(2)
        Dim hashBrownTask As Task(Of HashBrown) = FryHashBrownsAsync(3)
        Dim toastTask As Task(Of Toast) = MakeToastWithButterAndJamAsync(2)

        Dim breakfastTasks As New List(Of Task) From {eggsTask, hashBrownTask, toastTask}
        While breakfastTasks.Count > 0
            Dim finishedTask As Task = Await Task.WhenAny(breakfastTasks)
            If finishedTask Is eggsTask Then
                Console.WriteLine("eggs are ready")
            ElseIf finishedTask Is hashBrownTask Then
                Console.WriteLine("hash browns are ready")
            ElseIf finishedTask Is toastTask Then
                Console.WriteLine("toast is ready")
            End If
            Await finishedTask
            breakfastTasks.Remove(finishedTask)
        End While

        Dim oj As Juice = PourOJ()
        Console.WriteLine("oj is ready")
        Console.WriteLine("Breakfast is ready!")
    End Function

    Async Function MakeToastWithButterAndJamAsync(number As Integer) As Task(Of Toast)
        Dim toast As Toast = Await ToastBreadAsync(number)
        ApplyButter(toast)
        ApplyJam(toast)

        Return toast
    End Function

    Private Async Function ToastBreadAsync(slices As Integer) As Task(Of Toast)
        For slice As Integer = 0 To slices - 1
            Console.WriteLine("Putting a slice of bread in the toaster")
        Next
        Console.WriteLine("Start toasting...")
        Await Task.Delay(3000)
        Console.WriteLine("Remove toast from toaster")

        Return New Toast()
    End Function

    Private Async Function FryHashBrownsAsync(patties As Integer) As Task(Of HashBrown)
        Console.WriteLine($"putting {patties} hash brown patties in the pan")
        Console.WriteLine("cooking first side of hash browns...")
        Await Task.Delay(3000)
        For patty As Integer = 0 To patties - 1
            Console.WriteLine("flipping a hash brown patty")
        Next
        Console.WriteLine("cooking the second side of hash browns...")
        Await Task.Delay(3000)
        Console.WriteLine("Put hash browns on plate")

        Return New HashBrown()
    End Function

    Private Async Function FryEggsAsync(howMany As Integer) As Task(Of Egg)
        Console.WriteLine("Warming the egg pan...")
        Await Task.Delay(3000)
        Console.WriteLine($"cracking {howMany} eggs")
        Console.WriteLine("cooking the eggs ...")
        Await Task.Delay(3000)
        Console.WriteLine("Put eggs on plate")

        Return New Egg()
    End Function

    Private Function PourCoffee() As Coffee
        Console.WriteLine("Pouring coffee")
        Return New Coffee()
    End Function

    Private Function PourOJ() As Juice
        Console.WriteLine("Pouring orange juice")
        Return New Juice()
    End Function

    Private Sub ApplyJam(toast As Toast)
        Console.WriteLine("Putting jam on the toast")
    End Sub

    Private Sub ApplyButter(toast As Toast)
        Console.WriteLine("Putting butter on the toast")
    End Sub
End Module

このコードは、非同期の朝食タスクを約 15 分で完了します。 一部のタスクは同時に実行されるため、合計時間が短縮されます。 コードは複数のタスクを同時に監視し、必要に応じてアクションを実行します。

最後のコードは非同期です。 これは、人が朝食を作る方法をより正確に反映しています。 最後のコードと記事の最初のコード サンプルを比較します。 コア アクションは、コードを読み取ることで引き続き明確です。 最後のコードは、記事の冒頭に示すように、朝食を作るための手順の一覧を読むのと同じ方法で読むことができます。 AsyncキーワードとAwaitキーワードの言語機能は、すべての人が書かれた指示に従うために行う翻訳を提供します:タスクが完了するのを待っている間は、できる限りタスクを開始し、ブロックしないでください。

Async/await と ContinueWith

AsyncキーワードとAwait キーワードを使用すると、ContinueWithを直接使用する構文が簡略化されます。 Async / AwaitとContinueWithには非同期操作を処理するためのセマンティクスが似ていますが、コンパイラは必ずしもAwait式をContinueWithメソッド呼び出しに直接変換するとは限りません。 代わりに、コンパイラは、同じ論理動作を提供する最適化されたステート マシン コードを生成します。 この変換は、特に複数の非同期操作を連結する場合に、読みやすさと保守容易性に大きな利点をもたらします。

複数の順次非同期操作を実行する必要があるシナリオを考えてみましょう。 ContinueWith Async /と比較して、Awaitを使用して実装した場合の同じロジックの外観を次に示します。

ContinueWith の使用

ContinueWithでは、一連の非同期操作の各ステップにネストされた処理の継続が必要です。

' Using ContinueWith - demonstrates the complexity when chaining operations
Function MakeBreakfastWithContinueWith() As Task
    Return StartCookingEggsAsync() _
        .ContinueWith(Function(eggsTask)
                          Dim eggs = eggsTask.Result
                          Console.WriteLine("Eggs ready, starting bacon...")
                          Return StartCookingBaconAsync()
                      End Function) _
        .Unwrap() _
        .ContinueWith(Function(baconTask)
                          Dim bacon = baconTask.Result
                          Console.WriteLine("Bacon ready, starting toast...")
                          Return StartToastingBreadAsync()
                      End Function) _
        .Unwrap() _
        .ContinueWith(Function(toastTask)
                          Dim toast = toastTask.Result
                          Console.WriteLine("Toast ready, applying butter...")
                          Return ApplyButterAsync(toast)
                      End Function) _
        .Unwrap() _
        .ContinueWith(Function(butteredToastTask)
                          Dim butteredToast = butteredToastTask.Result
                          Console.WriteLine("Butter applied, applying jam...")
                          Return ApplyJamAsync(butteredToast)
                      End Function) _
        .Unwrap() _
        .ContinueWith(Sub(finalToastTask)
                          Dim finalToast = finalToastTask.Result
                          Console.WriteLine("Breakfast completed with ContinueWith!")
                      End Sub)
End Function

Async/Await の使用

Async / Awaitを使用する同じ操作のシーケンスは、ずっと自然に読み取れます。

' Using Async/Await - much cleaner and easier to read
Async Function MakeBreakfastWithAsyncAwait() As Task
    Dim eggs = Await StartCookingEggsAsync()
    Console.WriteLine("Eggs ready, starting bacon...")

    Dim bacon = Await StartCookingBaconAsync()
    Console.WriteLine("Bacon ready, starting toast...")

    Dim toast = Await StartToastingBreadAsync()
    Console.WriteLine("Toast ready, applying butter...")

    Dim butteredToast = Await ApplyButterAsync(toast)
    Console.WriteLine("Butter applied, applying jam...")

    Dim finalToast = Await ApplyJamAsync(butteredToast)
    Console.WriteLine("Breakfast completed with Async/Await!")
End Function

Async/Await が優先される理由

Async / Awaitアプローチには、いくつかの利点があります。

• 読みやすさ: コードは同期コードのように読み取り、操作のフローを理解しやすくなります。
• 保守容易性: シーケンス内のステップを追加または削除するには、最小限のコード変更が必要です。
• エラー処理: Try/Catch ブロックを使用した例外処理は自然に機能しますが、 ContinueWith では、障害が発生したタスクを慎重に処理する必要があります。
• デバッグ: Async/Awaitでは、呼び出し履歴とデバッガーのエクスペリエンスが大幅に向上します。
• パフォーマンス: Async/Await のコンパイラ最適化は、手動の ContinueWith チェーンよりも高度です。

チェーン操作の数が増えると、メリットがさらに明らかになります。 ContinueWithを使用して 1 つの継続を管理できますが、3 つまたは 4 つ以上の非同期操作のシーケンスはすぐに読み取りと保守が困難になります。 このパターンは、関数型プログラミングでは "モナディックド表記" と呼ばれ、複数の非同期操作を順番に読み取り可能な方法で作成できます。

こちらも参照ください

• Await 演算子
• 非同期
• チュートリアル: Async と Await を使用した Web へのアクセス (Visual Basic)
• Visual Basic における非同期返却型
• タスク ベースの非同期パターン (TAP)